Jump to: navigation, search

MoScript/Use Cases/Megamodel Population Part 1

< MoScript
Revision as of 07:02, 22 December 2011 by Wolfgangklingc.gmail.com (Talk | contribs)

(diff) ← Older revision | Latest revision (diff) | Newer revision → (diff)

Megamodel Population Part 1

A requisite for start working with MoScript is to count with a populated megamodel i.e, a megamodel with elements, which point to modeling artefacts. This megamodel population can be done through the AM3 graphical user interface, nevertheless Registering a high amount of models through the GUI is a repetitive and time consuming task. In those cases is better to use textual syntax to populate the megamodel, so, in this use case we are going to show how is possible to programmatically populate the Megamodel with MoScript. For this purpose we are going to populate it with the content of an ATL project that can be found in the ATL Transformations Zoo

Environment Preparation
  • Download the Families to Persons source code from here
  • Unzip the project and import it into eclipse
  • Create a MoScript project named megamodelPopulation with a file called megamodelPopulation.mscr
Registering the EMF metametamodel

As first step we are going to register programmatically the Ecore metametamodel in the Megamodel, to be able to register metamodels that conform to it and subsequently models that conform to those metamodels. For this, we have to have in mind that in order for MoScript to be able manipulate any model (remember that a metametamodel is also a model), the model must have at least an identifier to unequivocally identify it, a locator, to be able to locate the file that represents the model, and a reference model describing it, in order to be able to inspect its content.

If we check the Megamodels metamodel (that can be found in /org.eclipse.gmt.am3.platform.extension.globalmodelmanagement/model /GlobalModelManagement.ecore) we will see that a Metametamodel is a ReferenceModel and has references to identifier, locator and a ReferenceModel among others (see the picture bellow)
MoScript-MetaMetaModel.png MoScript-IdentifierLocator.png

The code for resgistering a MetaMetamodel in the Megamodel is the following:

program modelsDiscovery

do{
    -- Creates the Ecore metametamodel element in the megamodel
    thisModule.register(
        thisModule.metametamodel(
             thisModule.identifier('identifier', 'http://www.eclipse.org/emf/2002/Ecore', 'GlobalModelManagement::URI')
            ,thisModule.locator('locator', 'http://www.eclipse.org/emf/2002/Ecore', 
                                           'GlobalModelManagement::EPackagesRegistryLocator')
        )
    );
}

-- *********** Helper for creating the tuple for the element type
-- *********** Metametamodel
helper def: metametamodel(identifier : TupleType(name: String, concreteType: String, value :OclAny)
                          ,locator : TupleType(name: String, concreteType: String, value :OclAny))
:TupleType(name: String, concreteType: String, value :OclAny) =
 
	let id: String = identifier.value.asSequence()->first().value in
	let concreteType: String = 'GlobalModelManagement::Metametamodel' in
	let creationId: String = '@' + concreteType + '#' + id in
	let attributes : Set(TupleType(name: String, concreteType: String, value :OclAny)) = 
		Set{
			Tuple{name = '__id', concreteType = 'String', value = id},
			identifier, 
		    locator, 
		    Tuple{name = 'conformsTo', concreteType = 'GlobalModelManagement::ReferenceModel', value = creationId}
		} in 
	Tuple{creationId = creationId, concreteType = concreteType, value = attributes} 
; 

-- *********** Helper for creating the tuple for the element type 
-- *********** Identifier
helper def: identifier(attrName: String, value: String, concreteType: String) 
:TupleType(name: String, concreteType: String, value :OclAny) =

	let elementAttribute : Set(TupleType(name: String, concreteType: String, value :OclAny)) =
		Set{Tuple{name = 'value', concreteType = 'String', value = value}} in
	Tuple{name = attrName, concreteType = concreteType, value = elementAttribute}	
;

-- *********** Helper for creating the tuple for the element type 
-- *********** Locator
helper def: locator(attrName: String, value: String, concreteType: String) 
:TupleType(name: String, concreteType: String, value :OclAny) =

	let elementAttribute : Set(TupleType(name: String, concreteType: String, value :OclAny)) =
		Set{Tuple{name = 'value', concreteType = 'String', value = value}} in
	Tuple{name = attrName, concreteType = concreteType, value = elementAttribute}	
;

After running this program, you will notice that a MetaMetaModel element has been created in the megamodel as shown in the figure below. MoScript-MetaMetamodelRegistration.png

Code explanation

The operation that does the registration of a model in the Megamodel is register(model_element_tuple). The model_element_tuple parameter corresponds to a tuple with the following structure:

 TupleType(concreteType :String, value :Set(TupleType(...)))

Where

  • concreteType: Is a string with the concrete type of the model element to be created. The string must be in the form of Package::ConcreteType. For instance GlobalModelManagement::URI, GlobalModelManagement::ReferenceModel etc.
  • value: Corresponds to a set of attributes and references of the model element, each of them described again by a tuple as follows:
    • Attribute tuple:
      TupleType(attributeName :String, primitiveType :String, attributeValue :String)
    • Single value reference tuple:
      TupleType(creationId :String, referenceName :String, concreteType :String, referenceValue :Set(TupleType(...)))
      TupleType(referenceName: String, concreteType :String, creationId: String)
    • Multi value reference tuple:
      TupleType(referenceName :String, concreteType :String, referenceValue :Set(TupleType(...)))