Latest revision as of 09:36, 30 November 2017

Old information
This page is not updated anymore; for more up-to-date details look at the language specification at https://www.eclipse.org/viatra/documentation/addons.html instead.

Using VIATRA Viewers

The goal of the VIATRA Viewers component is to help developing model-driven user interfaces by filling and updating model viewer results with the results of model queries. The implementation relies on (and is modeled after) the Event-driven Virtual Machine and JFace Viewers libraries.

The VIATRA Viewers component can bind the results of queries to various JFace Viewers: JFace ListViewer and TreeViewers are currently supported, while TableViewer support is planned (see [bug 403325] for current state). Additionally, by installing extra features from the extra update site GraphViewers (based on GEF4 Zest) are also supported.

To select which patterns are used to determine the model elements to bind, several annotations are used by the framework. These annotations also allow to add labels and formatting to the viewers.

Using Viewer Annotations for Specifying the View Model

The VIATRA Viewers component uses four different annotations to bind query results to various viewers. As the different viewers have vastly different capabilities, all annotations are designed to be ignored if an unsupported annotation (or annotation parameter) is detected. Multiple patterns can have the same annotation type, in this case the Viewers component adds all the corresponding results to the viewer.

1. The Item annotation is used on patterns whose results will be the main elements to display in the viewers. E.g., in case of JFace Viewers the ContentProvider should return all the items.
2. The ContainsItem annotation is used on patterns whose results describe the the containment references between Items. E.g., in case of JFace TreeViewers the ContentProvider has to return these as child references.
3. The Edge annotation is used on patterns whose results describe a generic edge reference between Items. E.g., in case of Zest GraphViewers the ContentProvider will return these results as graph edges.
4. The Format annotation is used to define additional formatting. It is expected to be added next to Item and/or Edge annotations.

Binding Results to Viewers

Viewers Sandbox

1. Open the Query Explorer and Viewers Sandbox views.
2. Add your instance model and query definitions to the Query Explorer.
3. Select the Initialize VIATRA Viewers from a query definition in the popup menu over any selected element in the main area.
   • Warning: the VIATRA Sandbox does not update itself in case of pattern changes (as opposed to the Query Explorer).
   • The Initialize command uses the actual filter settings, but the Sandbox does not update itself if the filters are updated.

Programmatic Binding

1. Add a dependency to org.eclipse.viatra.addon.viewers.runtime (and org.eclipse.viatra.addon.viewers.runtime.zest if necessary) to your plug-in.
2. Create a ViewerState instance from a group of query specification. Useful (static) helper methods are available in the ViatraViewerDataModel class, that require a collection of query specifications; a data filter and the required features.
   • Collection of query specifications: only the query specifications with the corresponding Viewers annotations will be used; other specifications will be ignored.
   • ViewerDataFilter: it is used to filter the result of the queries by its parameters. For each pattern a separate filter can be initialized, that binds some of its parameters.
   • Required features: The ViewerStateFeature enum can be used to list the features required by the visualization. List viewers need no specific features; tree viewers require containment relations; Zest viewer requires edge relations (and possibly containment relations). Features not required will not create
3. Use the corresponding bind methods from ViatraViewers or ViatraGraphViewers classes on a manually created Viewer together with the ViewerState and your instance model.
   • The ViewerState instance can be re-used between different viewers.
   • If the filters added to the ViewerState are changed, all the viewers will become obsolete, and have to be redone.

Example

state = ViatraViewerDataModel.newViewerState( //Initializing state
  engine, //on a selected ViatraQueryEngine
  engine.getRegisteredQuerySpecifications(), //with all query specifications loaded to the selected engine
  ViewerDataFilter.UNFILTERED, //using no filters
  ImmutableSet.of(ViewerStateFeature.EDGE, ViewerStateFeature.CONTAINMENT)); //but requiring all features
ViatraGraphViewers.bind(graphViewer, state); //Binding viewer state to Zest graph viewer

Examples

UML visualization

To illustrate the approach, a simple example was prepared in the [examples repository of the VIATRA project] based on UML class diagrams. The examples are relying on the notion of example classes: UML classes that do not have operations or properties (neither in their parent classes).

To present most features of the framework, four specific patterns are used (for the entire implementations visit the git repository):

1. pattern emptyClass (cl : Class) - for listing all empty classes in the model
2. pattern nonEmptyClass(cl : Class) - for listing all classes in the model, that are not empty
3. pattern superClass(sub : Class, sup : Class) - for listing all direct superclass relations between classes
4. pattern transitiveSuperClass(sub : Class, sup : Class) - for listing all indirect superclass relations between classes (but not the direct ones)

The visualizer illustrations below correspond to the Test model in the repository.

JFace List Viewer example

List Viewers can be used to display a collection of elements as a list. To define the list, only the Item annotation is used. Its item parameter selects a pattern parameter, representing the data to display, while its label parameter is used to define a label string (with the same syntax as the label features of Data Binding or the labels of Validation Framework.

@Item(item = cl, label="Empty class $cl$")
pattern emptyClass(cl : Class) {
...
}
 
@Item(item = cl, label = "Class $cl$")
pattern nonEmptyClass(cl : Class) {
...
}

Binding contents to a JFace Tree Viewer

To support binding elements to a JFace Tree Viewer, in addition to the list of items, a set of containment relations needs also be specified using the ContainsItem annotation, that describes the container and contained items as pattern parameters. A containment reference is only displayed if both ends of the match result are present as Items in the viewer - otherwise it is simply ignored.

A unique property of the Tree Viewer support is that a single Item of the Viewers framework may appear multiple times in the tree. This happens if an element has multiple parents.

@ContainsItem(container = sup, item = sub)
pattern superClass(sub : Class, sup : Class) {
...
}
@Item(item = cl, label="Empty class $cl$")
pattern emptyClass(cl : Class) {
...
}
@Item(item = cl, label = "Class $cl$")
pattern nonEmptyClass(cl : Class) {
...
}

Additional notes

• In addition to basic binding support where all items appear both as root and child items as needed, it is possible to limit Items to appear only as root or only as child positions using the hierarchy parameter.
• If creating a TreeViewer binding programmatically, and an item appear in multiple places, make sure you set up the useHashLookup property of your TreeViewer, otherwise the update of the TreeViewer would fail.

Zest Graph Viewer example

The definition of graph viewers requires a set of Items and a set of Edges. Edges are connecting two different Items; edges where the end points are not Items are not displayed. As opposed to the Tree Viewer support, a single item only appears once.

Additionally, based upon the formatting capabilities of Zest some basic display options are available in the form of Format annotation. The various parameters can be used to depict colors, line width, etc. If a selected format is not applicable for the current element, it is simply ignored.

@Edge(source = sup, target = sub, label = "direct")
@Format(color = "#7f004b", lineWidth = 2)
pattern superClass(sub : Class, sup : Class) {
...
}
@Edge(source = sup, target = sub)
pattern transitiveSuperClass(sub : Class, sup : Class) {
...
}
@Item(item = cl, label="Empty class $cl$")
@Format(color="#3770d7", textColor = "#ffffff")
pattern emptyClass(cl : Class) {
...
}
@Item(item = cl, label = "Class $cl$")
pattern nonEmptyClass(cl : Class) {
...
}

Ecore visualization

We have developed another demonstrating example in the context of the Headless Execution example. As the queries of the Headless Example match against .ecore models (that is, EMF metamodels), the visualization example below can be used to visualize metamodels and containment relationships in a simple way. This example is focused mainly on the 2D graph visualization supported by the GEF4 Zest framework.

Specification

The example defines two graph node types and three graph edge types (code):

• Nodes are EPackage and EClass instances
• Edges are classes contained in a package, subpackage relationships, and a special transitive containment relationship between packages and classes classes in a package hierarchy that enumerates all classes that are contained by a root package or some subpackage (transitively) below this root.

@Item(item = p, label = "P: $p.name$")
@Format(color = "#791662", textColor = "#ffffff")
pattern ePackage(p : EPackage) { EPackage(p); }
 
@Item(item = ec, label = "EC: $ec.name$")
@Format(color = "#e8da2c")
pattern eClass(ec : EClass) { EClass(ec); }
 
@Edge(source = p, target = ec, label = "classIn")
pattern classesInPackage(p : EPackage, ec: EClass) { EPackage.eClassifiers(p,ec); }
 
@Edge(source = p, target = sp, label = "sub")
pattern subPackage(p: EPackage, sp: EPackage){ EPackage.eSubpackages(p,sp); }
 
@Edge(source = rootP, target = containedClass, label = "classIn+")
@Format(color = "#0033ff")
pattern classesInPackageHierarchy(rootP: EPackage, containedClass: EClass)
{
	find classesInPackage(rootP,containedClass);
} or {
	find subPackage+(rootP,somePackage);
	find classesInPackage(somePackage,containedClass);
}

Visualization

The visualization of a simple test model (file) is illustrated in the figure.

Observe the following details:

• EPackages and EClasses are shown in purple and yellow, respectively
• direct relationships (subpackage and contained packages) are shown in grey
• inferred transitive containment relationships are shown in blue